From 2cfd5153a2cd25f5513a9c6aa72196691dd74d19 Mon Sep 17 00:00:00 2001
From: Peter Odding <peter@peterodding.com>
Date: Sun, 4 Sep 2011 14:59:22 +0200
Subject: Functions to manage Vim buffers with generated contents

---
 buffer.vim | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 buffer.vim

diff --git a/buffer.vim b/buffer.vim
new file mode 100644
index 0000000..e4472e6
--- /dev/null
+++ b/buffer.vim
@@ -0,0 +1,37 @@
+" Vim auto-load script
+" Author: Peter Odding <peter@peterodding.com>
+" Last Change: September 4, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+function! xolox#misc#buffer#is_empty()
+  " Check if the current buffer is an empty, unchanged buffer which can be reused.
+  return !&modified && expand('%') == '' && line('$') <= 1 && getline(1) == ''
+endfunction
+
+function! xolox#misc#buffer#prepare(bufname)
+  let bufname = '[' . a:bufname . ']'
+  let buffers = tabpagebuflist()
+  call map(buffers, 'fnamemodify(bufname(v:val), ":t:r")')
+  let idx = index(buffers, bufname)
+  if idx >= 0
+    execute (idx + 1) . 'wincmd w'
+  elseif !(xolox#misc#buffer#is_empty() || expand('%:t') == bufname)
+    vsplit
+  endif
+  silent execute 'edit' fnameescape(bufname)
+  lcd " clear working directory
+  setlocal buftype=nofile bufhidden=hide noswapfile
+  let &l:statusline = bufname
+  call xolox#misc#buffer#unlock()
+  silent %delete
+endfunction
+
+function! xolox#misc#buffer#lock()
+  " Lock a special buffer so it can no longer be edited.
+  setlocal readonly nomodifiable nomodified
+endfunction
+
+function! xolox#misc#buffer#unlock()
+  " Unlock a special buffer so that its content can be updated.
+  setlocal noreadonly modifiable
+endfunction
-- 
cgit v1.2.3